zpoly.f

Go to the documentation of this file.

C                  CVM Class Library
C                  http://cvmlib.com
C
C          Copyright Sergei Nikolaev 1992-2013
C Distributed under the Boost Software License, Version 1.0.
C    (See accompanying file LICENSE_1_0.txt or copy at
C          http://www.boost.org/LICENSE_1_0.txt)
C
C
C     Matrix polynom
C
C     Input/Output parameters:
C
C     M     - size of input square matrix (input)
C     A     - matrix (input)
C     LDA   - leading dimension of A (int)(input)
C     N     - size of coefficient array V (input)
C     V     - coefficient array (input)
C     P     - result square matrix (output) = V(1)*I + V(2)*A + V(3)*A^2 + ... + V(N)*A^(N-1)
C     LDP   - leading dimension of P (int)(input)
C     B     - working array of size NPOLY (M, N)

      SUBROUTINE zpoly (M, A, LDA, N, V, P, LDP, B)
CDEC$ IF DEFINED (FTN_EXPORTS)
CDEC$     ATTRIBUTES DLLEXPORT::ZPOLY
CDEC$ ENDIF
      INTEGER m, n, lda, ldp
      DOUBLE COMPLEX a(lda*m), v(n), p(ldp*m), b(1)
      INTEGER i, k, ns, nr, nqsr, mm, nrm, nwrk
      DOUBLE COMPLEX cone /(1.d0,0.d0)/, czero /(0.d0,0.d0)/
      DOUBLE PRECISION q
      CHARACTER trans /'N'/
      INTEGER npoly
      INTEGER floor, ceiling

      IF (m .LE. 0) RETURN
      mm  = m * m

      CALL zscal(mm, czero, p, 1)
      IF (n .LE. 0) RETURN

      DO 10 i = 0, m-1
          p(i*(ldp+1)+1) = v(1)
10    CONTINUE

      IF (n .EQ. 1) RETURN

      q    = dfloat(n - 1)        ! b(0) is V(1)
      ns   = ceiling(dsqrt(q))
      nr   = floor(q / dfloat(ns))
      nqsr = n - 1 - ns * nr        ! q - sr
      nrm  = (nr + 1) * mm + 1      ! the 1st el. of the last matrix

      nwrk = npoly(m, n)
      DO 15 i = mm + 1, nwrk
          b(i) = czero
15    CONTINUE

      CALL zcopym(m, m, a, lda, b, m)   ! the first of these matrices
                                         ! will contain powers of A
      DO 20 k = 1, nr
          DO 30 i = 1, mm, m + 1
              b(mm * k + i) = v(ns * k + 1)  ! b(i)*I
30        CONTINUE
20    CONTINUE

      DO 40 i = 1, ns - 1
          CALL zaxpym(m, m, v(i + 1), b, m, p, ldp)

          DO 50 k = 1, nr - 1
              CALL zaxpy(mm, v(ns * k + i + 1), b, 1,
     1                                           b(k * mm + 1), 1)
50        CONTINUE

          IF (i .LE. nqsr) THEN
              CALL zaxpy(mm, v(ns * nr + i + 1), b, 1,
     1                                           b(nr * mm + 1), 1)
          ENDIF

          CALL zcopy(mm, b, 1, b(nrm), 1)
          CALL zgemm(trans, trans, m, m, m, cone, b(nrm), m, a, lda,
     1                                           czero, b, m)
40    CONTINUE

      CALL zgemm(trans, trans, m, m, m, cone, b(mm + 1), m,
     1                                           b, m, cone, p, ldp)

      IF (nr .GT. 1) CALL zcopy(mm, b, 1, b(nrm), 1)

      DO 60 k = 2, nr
          CALL zcopy(mm, b, 1, b(mm + 1), 1)
          CALL zgemm(trans, trans, m, m, m, cone, b(mm + 1), m,
     1                                          b(nrm), m, czero, b, m)
          CALL zgemm(trans, trans, m, m, m, cone, b(k * mm + 1), m,
     1                                          b, m, cone, p, ldp)
60    CONTINUE

      RETURN
      END !SUBROUTINE ZPOLY